<-
Apache > Serveur HTTP > Documentation > Version 2.4

Les expressions dans le serveur HTTP Apache

Langues Disponibles:  en  |  fr 

Historiquement, il existe de nombreuses variantes dans la syntaxe des expressions permettant d'exprimer une condition dans les différents modules du serveur HTTP Apache. À ce titre, des travaux sont en cours pour n'utiliser qu'une seule variante nommée ap_expr, pour toutes les directives de configuration. Ce document décrit l'interpréteur d'expressions ap_expr.

Le type d'expression ap_expr est appelé à remplacer la plupart des autres types d'expressions dans HTTPD. Par exemple, la directive obsolète SSLRequire peut être remplacée par la directive Require expr.

Voir aussi

top

Syntaxe en Forme de Backus-Naur

La Forme de Backus-Naur (souvent abrégée en BNF, de l'anglais Backus-Naur Form) est une notation permettant de décrire les règles syntaxiques des langages de programmation. En général, les expressions représentent des valeurs booléennes. Dans ce cas, le point de départ de la BNF est expr. Cependant, certaines directives comme LogMessage utilisent comme paramètres des expressions qui représentent des chaînes de caractères. Dans ce cas, le point de départ de la BNF est string.

expr        ::= "true" | "false"
              | "!" expr
              | expr "&&" expr
              | expr "||" expr
              | "(" expr ")"
              | comp

comp        ::= stringcomp
              | integercomp
              | unaryop word
              | word binaryop word
              | word "in" "{" wordlist "}"
              | word "in" listfunction
              | word "=~" regex
              | word "!~" regex


stringcomp  ::= word "==" word
              | word "!=" word
              | word "<"  word
              | word "<=" word
              | word ">"  word
              | word ">=" word

integercomp ::= word "-eq" word | word "eq" word
              | word "-ne" word | word "ne" word
              | word "-lt" word | word "lt" word
              | word "-le" word | word "le" word
              | word "-gt" word | word "gt" word
              | word "-ge" word | word "ge" word

wordlist    ::= word
              | wordlist "," word

word        ::= word "." word
              | digit
              | "'" string "'"
              | """ string """
              | variable
	      | rebackref
              | function

string      ::= stringpart
              | string stringpart

stringpart  ::= cstring
              | variable
	      | rebackref

cstring     ::= ...
digit       ::= [0-9]+

variable    ::= "%{" varname "}"
              | "%{" funcname ":" funcargs "}"

rebackref   ::= "$" [0-9]

function     ::= funcname "(" word ")"

listfunction ::= listfuncname "(" word ")"
top

Variables

L'interpréteur d'expressions fournit plusieurs variables de la forme %{HTTP_HOST}. Notez que la valeur d'une variable peut dépendre de la phase du traitement de la requête au cours de laquelle elle est évaluée. Par exemple, une expression utilisée dans une directive <If > sera évaluée avant la phase d'authentification. Par conséquent, la variable %{REMOTE_USER} ne sera pas encore définie à ce stade.

Les variables suivantes contiennent la valeur de l'en-tête de requête HTTP correspondant. La fonction req permet d'extraire les valeurs des autres en-têtes. L'utilisation de ces variables peut provoquer l'ajout du nom d'en-tête correspondant à l'en-tête Vary de la réponse HTTP, sauf spécification contraire pour la directive qui accepte l'expression comme paramètre. La function req_novary permet de modifier ce comportement.

Nom
HTTP_ACCEPT
HTTP_COOKIE
HTTP_FORWARDED
HTTP_HOST
HTTP_PROXY_CONNECTION
HTTP_REFERER
HTTP_USER_AGENT

Autres variables liées aux requêtes

NomDescription
REQUEST_METHOD La méthode HTTP de la requête entrante (par exemple GET)
REQUEST_SCHEME Le protocole associé à l'URI de la requête
REQUEST_URI La partie chemin de l'URI de la requête
DOCUMENT_URI Idem REQUEST_URI
REQUEST_FILENAME Le chemin complet dans le système de fichiers local du fichier ou du script correspondant à la requête, si le serveur l'a dèjà déterminé à l'instant où REQUEST_FILENAME est référencée. Dans le cas contraire, comme dans un contexte de serveur virtuel, même valeur que REQUEST_URI
SCRIPT_FILENAME Identique à REQUEST_FILENAME
LAST_MODIFIED La date et heure de dernière modification du fichier au format 20101231235959, si elle est déjà connue du serveur au moment où LAST_MODIFIED est référencé.
SCRIPT_USER Le nom d'utilisateur du propriétaire du script.
SCRIPT_GROUP Le nom du groupe auquel appartient le script.
PATH_INFO L'information relative au nom de chemin située en fin, voir la directive AcceptPathInfo
QUERY_STRING La chaîne de paramètres de la requête courante
IS_SUBREQ "true" si la requête courante est une sous-requête, "false" dans le cas contraire
THE_REQUEST La requête complète (par exemple "GET /index.html HTTP/1.1")
REMOTE_ADDR L'adresse IP de l'hôte distant
REMOTE_HOST Le nom d'hôte de l'hôte distant
REMOTE_USER Le nom de l'utilisateur authentifié, s'il existe (non disponible à l'intérieur d'un bloc <If >)
REMOTE_IDENT Le nom de l'utilisateur défini par mod_ident
SERVER_NAME La valeur de la directive ServerName du serveur virtuel courant
SERVER_PORT Le port associé au serveur virtuel courant ; voir la directive ServerName
SERVER_ADMIN La valeur de la directive ServerAdmin du serveur virtuel courant
SERVER_PROTOCOL Le protocole utilisé par la requête
DOCUMENT_ROOT La valeur de la directive DocumentRoot du serveur virtuel courant
AUTH_TYPE La valeur de la directive AuthType (par exemple "basic")
CONTENT_TYPE Le type de contenu de la réponse (non disponible à l'intérieur d'un bloc <If >)
HANDLER Le nom du gestionnaire qui a généré la réponse
HTTPS "on" si la requête utilise https, "off" dans le cas contraire
IPV6 "on" si la connexion utilise IPv6, "off" dans le cas contraire
REQUEST_STATUS Le code d'erreur HTTP de la requête (non disponible à l'intérieur d'un bloc <If >)
REQUEST_LOG_ID L'identifiant du message d'erreur associé à la requête (voir la directive ErrorLogFormat)
CONN_LOG_ID L'identifiant du message d'erreur associé à la connexion (voir la directive ErrorLogFormat)
CONN_REMOTE_ADDR L'adresse IP du correspondant pour la connexion (voir le module mod_remoteip)
CONTEXT_PREFIX
CONTEXT_DOCUMENT_ROOT

Variables diverses

NomDescription
TIME_YEAR L'année courante (par exemple 2010)
TIME_MON Le mois courant (1, ..., 12)
TIME_DAY Le jour courant dans le mois
TIME_HOUR Les heures de la date courante (0, ..., 23)
TIME_MIN Les minutes de la date courante
TIME_SEC Les secondes de la date courante
TIME_WDAY Le jour de la semaine (à partir de 0 pour dimanche)
TIME La date et heure au format 20101231235959
SERVER_SOFTWARE La chaîne contenant la version du serveur
API_VERSION La date de la version de l'API (module magic number)

Certains modules, comme mod_ssl, définissent des variables supplémentaires.

top

Opérateurs binaires

À l'exception de quelques opérateurs de comparaison internes, les opérateurs binaires sont de la forme "-[a-zA-Z][a-zA-Z0-9_]+", autrement dit un signe moins et au moins deux caractères. Le nom est insensible à la casse. Les modules peuvent fournir des opérateurs binaires supplémentaires.

Opérateurs de comparaison

NomAlternative Description
== = Egalité de chaînes
!= Inégalité de chaînes
< Chaîne inférieure à
<= Chaîne inférieure ou égale à
> Chaîne supérieure à
>= Chaîne supérieure ou égale à
-eq eq Egalité d'entiers
-ne ne Inégalité d'entiers
-lt lt Entier inférieur à
-le le Entier inférieur ou égal à
-gt gt Entier supérieur à
-ge ge Entier supérieur ou égal à

Autres opérateurs binaires

NomDescription
-ipmatch L'adresse IP correspond à adresse/masque
-strmatch la chaîne de gauche correspond au modèle constitué par la chaîne de droite (contenant des caractères génériques *, ?, [])
-strcmatch idem -strmatch, mais insensible à la casse
-fnmatch idem -strmatch, mais les slashes ne sont pas pris en compte par les caractères génériques
top

Opérateurs unaires

Les opérateurs unaires acceptent un seul argument et sont de la forme "-[a-zA-Z]", autrement dit le signe moins et un caractère. Le nom est sensible à la casse. Les modules peuvent fournir des opérateurs unaires supplémentaires.

NomDescriptionRestreint
-d L'argument est traité comme un nom de fichier. Vrai si le fichier existe et correspond à un répertoireoui
-e L'argument est traité comme un nom de fichier. Vrai si le fichier (ou dir ou special) existeoui
-f L'argument est traité comme un nom de fichier. Vrai si le fichier existe et correspond à un fichier régulieroui
-s L'argument est traité comme un nom de fichier. Vrai si le fichier existe et n'est pas videoui
-L L'argument est traité comme un nom de fichier. Vrai si le fichier existe et correspond à un lien symboliqueoui
-h L'argument est traité comme un nom de fichier. Vrai si le fichier existe et correspond à un lien symbolique (identique à -L)oui
-F Vrai si la chaîne correspond a un fichier valide, accessible avec tous les contrôles d'accès configurés pour ce chemin. A cette fin, une sous-requête effectue la vérification, et vous devez utiliser ce drapeau avec soin car il peut impacter les performances de votre serveur !
-U Vrai si la chaîne correspond a une URL valide, accessible avec tous les contrôles d'accès configurés pour ce chemin. A cette fin, une sous-requête effectue la vérification, et vous devez utiliser ce drapeau avec soin car il peut impacter les performances de votre serveur !
-A Alias pour -U
-n Vrai si la chaîne n'est pas vide
-z Vrai si la chaîne est vide
-T Faux si la chaîne est vide, "0", "off", "false", ou "no" (insensibilité à la casse). Vrai dans le cas contraire.
-R Idem "%{REMOTE_ADDR} -ipmatch ...", en plus efficace

Les opérateurs marqués comme "restreints" ne sont pas disponibles avec certains modules comme mod_include.

top

Fonctions

Normalement, les fonctions dont la valeur est une chaîne acceptent une chaîne comme argument et renvoient une chaîne. Les noms de fonctions sont insensibles à la casse. Les modules peuvent fournir des fonctions supplémentaires.

NomDescriptionRestreint
req, http Lit l'en-tête de requête HTTP ; les noms d'en-tête correspondants peuvent être ajoutés à l'en-tête Vary, voir ci-dessous
req_novary Identique à req, mais aucun nom d'en-tête n'est ajouté à l'en-tête Vary
resp Lit l'en-tête de réponse HTTP
reqenv Recherche une variable d'environnement de requête (on peut aussi utiliser le raccourci v).
osenv Recherche une variable d'environnement du système d'exploitation
note Recherche une note de requête
env Renvoie le premier résultat positif de note, reqenv, osenv
tolower Convertit une chaîne en minuscules
toupper Convertit une chaîne en majuscules
escape Echappe les caractères spéciaux en codage hexadécimal
unescape "Déséchappe" les chaînes codées en hexadécimal, en ne gardant encodés que les slashes; renvoie la chaîne vide si la séquence %00 est rencontrée
base64 Encode la chaîne en base64
unbase64 Décode les chaînes codées en base64, renvoie une chaîne tronquée si le caractère 0x00 est rencontré
md5 Génère un hash de la chaîne en utilisant MD5, puis code le hash obtenu en hexadécimal
sha1 Génère un hash de la chaîne en utilisant SHA1, puis encode le hash obtenu en hexadécimal
file Lit le contenu d'un fichieroui
filesize Renvoie la taille d'un fichier (ou 0 si le fichier n'existe pas ou ne correspond pas à un fichier régulier)oui

Les fonctions marquées comme "restreints" ne sont pas disponibles avec certains modules comme mod_include.

Lorsque les fonctions req ou http sont utilisées, le nom d'en-tête sera automatiquement ajouté à l'en-tête Vary de la réponse HTTP, sauf spécification contraire pour la directive qui accepte l'expression comme paramètre. La fonction req_novary permet d'empêcher l'ajout de noms d'en-têtes à l'en-tête Vary.

En plus des fonctions dont la valeur est une chaîne, il existe aussi des fonctions dont la valeur est une liste, qui acceptent une chaîne comme argument, et renvoient une liste de mots, autrement dit une liste de chaînes. La liste de mot peut être utilisée avec l'opérateur spécial -in. Les noms de fonctions sont insensibles à la casse. Les modules peuvent fournir des fonctions supplémentaires.

Il n'existe pas de fonctions internes dont la valeur est une liste. Le module mod_ssl fournit la fonction PeerExtList. Voir la description de la directive SSLRequire pour plus de détails (notez que la fonction PeerExtList peut aussi être utilisée en dehors de la directive SSLRequire).

top

Exemples d'expressions

Les exemples suivants montent comment utiliser les expressions pour évaluer les requêtes :

# Comparer le nom d'hôte avec example.com et rediriger vers
# www.example.com si le nom d'hôte correspond
<If "%{HTTP_HOST} == 'example.com'">
    Redirect permanent / http://www.example.com/
</If>

# Forcer le type text/plain si un fichier fait l'objet d'une
# requête dont la chaîne de paramètres contient 'forcetext'
<If "%{QUERY_STRING} =~ /forcetext/">
    ForceType text/plain
</If>

# N'autoriser l'accès à ce contenu que pendant les heures de
# travail
<Directory "/foo/bar/business">
     Require expr %{TIME_HOUR} -gt 9 && %{TIME_HOUR} -lt 17
</Directory>
top

Autres

NomAlternative Description
-in in chaîne contenue dans une liste de chaînes
/regexp/ m#regexp# Expression rationnelle (la seconde forme permet de spécifier des délimiteurs autres que /)
/regexp/i m#regexp#i Expression rationnelle insensible à la casse
$0 ... $9 Références arrières dans les expressions rationnelles

Références arrières dans les expressions rationnelles

Les chaînes $0 ... $9 permettent de référencer les groupes de capture en provenance d'expressions rationnelles précédemment exécutées et mises en correspondance avec succès. Elles ne peuvent normalement être utilisées que dans la même expression que celle mise en correspondance, mais certains modules permettent de les utiliser de manière spéciale.

top

Comparaison avec SSLRequire

La syntaxe ap_expr consiste principalement en une surcouche de la syntaxe de la directive obsolète SSLRequire. Vous pouvez consulter la liste de leur différences dans la documentation de la directive SSLRequire.

top

Historique de version

La fonction req_novary est disponible à partir de la version 2.4.4 du serveur HTTP Apache.

Langues Disponibles:  en  |  fr 

top

Commentaires

Notice:
This is not a Q&A section. Comments placed here should be pointed towards suggestions on improving the documentation or server, and may be removed again by our moderators if they are either implemented or considered invalid/off-topic. Questions on how to manage the Apache HTTP Server should be directed at either our IRC channel, #httpd, on Freenode, or sent to our mailing lists.